ladyonthemoon

making of
[Skyrim] [Skyrim SE] My Own Alternate Start (or How to make an alternate start)

Purpose:

This thread is about how I'm making an alternate start mod, avoiding the usual beginning in the cart, the execution scene and having to choose a side in the civil war.

Permissions:

This tutorial is just for your information, you are not allowed to use it to remake this mod and upload it to Bethesda.net or anywhere else.

You can use this tutorial as a guide that will help you make your own alternate start; just don't forget to credit me and put a link to this place when you release your creation.

Where to download the mod:

Note:

There is no way to create an alternate start mod without modifying the main quest (MQ101). Knowing this, the amount of modifications you'll make to MQ101 is irrelevant; modified is modified, whatever the number of things you change in this quest.

Let's create the new start conditions

Workflow:

1) Setting the start conditions:

  • let's  create the place(s) where the player will start. In the finished mod, there will be five possible places, for now I've created the gate to Cyrodiil one, in cell 6, -29, by adding a marker heading that I named "MOAS_CyrodiilGateMarker". This is where the player will be teleported when I choose that location at the start of the game. Once the player has been teleported, the character creation menu will pop up.

Capture4.thumb.JPG.2ad3d4c5c84aee381d6dfe6f4dbb4cdd.JPG

  • let's  modify the dummy player's inventory. In "Actors/Actor" open the "Player" generic form and modify the content of the inventory to your liking. I personally modified the player outfit so that it contains ordinary farm clothes and boots, a basic set of weapons, food, drinks and potions. The idea is that the player was forced to leave whatever province they were living in such a hurry that they kept only what they were wearing.
  • let's  modify the quick start global. In "Miscellaneous/Global, find "MQQuickstart" and set it to 5:

Capture.JPG.5674e37628beec6bbada65333fb8158d.JPG

2) Setting the new start stage in MQ101:

  • in "Character/Quest", let's find "MQ101",
  • in stage 0, let's create a new empty log entry,
  • let's add to it the condition "GetGlobalValue" | "MQQuickStart" | "== 5",

Capture2.thumb.JPG.35e4d4c200f0247081e4d0ec3d1b186d.JPG

In the Papyrus Fragment:

  • in the kmyQuest drop down menu, let's choose "MQ101QuestScript"; this is required so that the start script can access the AddRaceSpells function it contains.
  • let's save the quest now; this is needed otherwise the CK will spit error messages if we add the script directly,
  • let's add the start script.

Capture3.thumb.JPG.af7554ca74ac2dff8f8d64dc631d922d.JPG

Here is the script I'm adding; it contains the necessary so that the mod works:

;starting game
;setting the time to 8 am
GameHour.SetValue(8)

Actor PlayerRef = Game.GetPlayer()

;moving the player to the chosen start place
PlayerRef.MoveTo(MOAS_CyrodiilGateMarker)

;fading the game out
Game.FadeOutGame(False, true, 1.0, 1.0)

;removing prisoner outfit
PlayerRef.RemoveItem(ClothesPrisoner, abSilent = true)
PlayerRef.RemoveItem(ClothesPrisonerShoes, abSilent = true)
PlayerRef.RemoveItem(PrisonerCuffsPlayer, abSilent = true)
Utility.Wait(1)

;character creation
;popping up race menu
Game.ShowRaceMenu()
;add spells based on race
kmyQuest.AddRaceSpells()
Utility.Wait(1)

;enabling save
Game.SetInChargen(false, true, true)
;saving game once the character has been created
Game.RequestSave()

3) Choosing where to start and how it looks like in game:

First, all the locations where the player will be able to start the game must be created:

  1. chose a cell in the world (make sure the place is not outside the borders of Skyrim),
  2. add a "xmarkerheading" in that cell and give it a name.

Second, the message that will pop up asking the player where they are from must be created:

  • in Miscellaneous/Message, create a message like the one below

Capture5.thumb.JPG.e73566629e7690997c0dc947f78dd87e.JPG

Now the start script must be modified accordingly (I've added to it an option so that the weather is clear during character creation):

;starting game
;setting the time to 8 am
GameHour.SetValue(8)

Actor PlayerRef = Game.GetPlayer()

;choosing where the player comes from
;moving the player to a dummy location first so that the choice message can display
;moving the player to the chosen start place
PlayerRef.moveto(MOAS_CyrodiilGateMarker)
Int StartButton = MOAS_StartChoiceMessage.Show ()
if StartButton == 0
	PlayerRef.MoveTo(MOAS_CyrodiilGateMarker)
	elseif StartButton == 1
		PlayerRef.MoveTo(MOAS_HammerfellGateMarker)
	elseif StartButton == 2
		PlayerRef.MoveTo(MOAS_HighRockBorderMarker)
	elseif StartButton == 3
		PlayerRef.MoveTo(MOAS_MorrowindBorderNorthMarker)
	elseif StartButton == 4
		PlayerRef.MoveTo(MOAS_MorrowindSouthGateMarker)
Endif

;fading the game out
Game.FadeOutGame(False, true, 1.0, 1.0)

;removing prisoner outfit
PlayerRef.RemoveItem(ClothesPrisoner, abSilent = true)
PlayerRef.RemoveItem(ClothesPrisonerShoes, abSilent = true)
PlayerRef.RemoveItem(PrisonerCuffsPlayer, abSilent = true)
Utility.Wait(1)

;setting weather
SkyrimClear.ForceActive(true)

;character creation
;popping up race menu
Game.ShowRaceMenu()
;adding spells based on race
kmyQuest.AddRaceSpells()
Utility.Wait(1)

;enabling save
Game.SetInChargen(false, true, true)
;saving game once the character has been created
Game.RequestSave()

When you start the game, the message will pop up, asking you to choose a place for your player to start the game and you'll be able to create your character:

20171224175826_1.thumb.jpg.d09140fa19ac1b21a1880b2d36aff8f0.jpg

20171224175840_1.thumb.jpg.c6153b5331dd0d69a2ab137464cf8336.jpg

20171224175944_1.thumb.jpg.eab27012e430315cc94a08cd00aac71a.jpg

20171224175958_1.thumb.jpg.6a5f156ba29d41afb73c15ec29cb7520.jpg

20171224180030_1.thumb.jpg.bbd5b1327d2053e1f6acb3dc8b3e6fb6.jpg

20171224180042_1.thumb.jpg.0dd5d73e034ddf9e0b4c5e5d3ff5e79b.jpg

20171224182853_1.thumb.jpg.4627c2a1b940ef340fcc18c8b9733484.jpg

20171224182912_1.thumb.jpg.a1c81e3ecd48fc1fb65a709369797596.jpg

20171224180404_1.thumb.jpg.346d1874d0cdc950685645e2174b7879.jpg

20171224180416_1.thumb.jpg.4ffe869530d483cb611be3b0a2c0170a.jpg

-----oOo-----

A bit of mod cleaning

 

Quote
  • let's  modify the dummy player's inventory. In "Actors/Actor" open the "Player" generic form and modify the content of the inventory to your liking.

That's what I wrote earlier, but, it's actually not that a good idea. It's better if we do this by script.

Before that, we need to remove the changes that were made to the player base form. In order to do that, launch the CK, select your plugin, set it active and then click on the button "Details":

  1. in the "Files Details" dialogue box that opens, select "Player",
  2. press the "DEL" key,
  3. the CK will ask confirmation that you want the modifications made to the player to be ignored,
  4. click on "Yes",
  5. load your plugin and save it immediately.

Capture6.thumb.JPG.78218b547ef3c30ccfadd8774f5e5b32.JPG

Note:

This is how you must proceed each time you make unwanted modifications to the game; you can select several records at the same time.

When you accidentally modify references in a cell, you'll have to use this method to undo the changes you made to the references first and redo the whole operation to undo the modifications made to the cells themselves.

It's good to use that same method when you want to remove objects you created, whatever the object, levelled list, form, package, quest and so on, instead of simply deleting them.

Tips:

  • when you add objects to a place, give them a recognisable name,
  • when you accidentally modify an existing reference in a cell, give them a name too; a name like "Delete" or "Undo",

so that you can spot them more easily in the "File Details" window.

For example, I added a boat and two oars near the place where the player spawns when I choose "High Rock". I named them "MOAS_Boad" and "MOAS_Oar01" and "MOAS_Oar02" making them recognisable in the "Files Details".

Capture7.thumb.JPG.e2783e257518972bace4c949c3dfaf3e.JPG

-----oOo-----

Now that the changes made to the player base form have been undone, we need to remake them by script.

4) Let's modify the player by script:

To do so, we need to remove all the clutter that are in its inventory and add the new stuff, by adding the lines:

;emptying player's inventory
;adding new outfit and stuff to the player
PlayerRef.RemoveAllItems()
PlayerRef.SetOutfit(MOAS_PlayerOutfit)
PlayerRef.AddItem(MOAS_PlayerStartPackage, 1)
  • MOAS_PlayerOutfit is an "outfit" form that contains levelled lists of the clothes, boots and gloves that will be randomly equipped to the player,
  • MOAS_PlayerStartPackage is a levelled list that contains the rest: weapons, food, potions, money and so on, that will also be randomly added to the player's inventory.

The new script looks now like that:

;starting game
;setting the time to 8 am
GameHour.SetValue(8)

Actor PlayerRef = Game.GetPlayer()

;moving the player to a dummy location (necessary so that the choice message displays correctly)
PlayerRef.MoveTo(MOAS_DummyCellMarker)

;choosing where the player comes from
Int StartButton = MOAS_StartChoiceMessage.Show ()
if StartButton == 0
	PlayerRef.MoveTo(MOAS_CyrodiilGateMarker)
	ElseIf StartButton == 1
		PlayerRef.MoveTo(MOAS_HammerfellGateMarker)
	ElseIf StartButton == 2
		PlayerRef.MoveTo(MOAS_HighRockBorderMarker)
	ElseIf StartButton == 3
		PlayerRef.MoveTo(MOAS_MorrowindBorderNorthMarker)
	ElseIf StartButton == 4
		PlayerRef.MoveTo(MOAS_MorrowindSouthGateMarker)
Endif

;fading the game out
Game.FadeOutGame(False, true, 1.0, 1.0)

;emptying player's inventory
;adding new outfit and stuff to the player
PlayerRef.RemoveAllItems()
PlayerRef.SetOutfit(MOAS_PlayerOutfit)
PlayerRef.AddItem(MOAS_PlayerStartPackage, 1)
Utility.Wait(1)

;setting weather
SkyrimClear.ForceActive(true)
Utility.Wait(1)

;character creation
;popping up race menu
Game.ShowRaceMenu()
;adding spells based on race
kmyQuest.AddRaceSpells()
Utility.Wait(1)

;enabling save
Game.SetInChargen(false, true, true)
;saving game once the character has been created
Game.RequestSave()
  • MOAS_DummyCellMarker is a marker I added to an interior cell I created and named MOAS_DummyCell. This cell contains only the xmarkerheading because it's just used during the time the message "Where are you coming from?" displays. Teleporting the player to that cell is necessary; otherwise the message will not show correctly and selecting a destination will not be possible. (In the previous versions of the script, I had teleported the player to the Cyrodiil border but it's actually preferable to create a new cell.)
  • fading the game out (Game.FadeOutGame(False, true, 1.0, 1.0)) is necessary; otherwise the screen will remain black.

For now, the mod as it is is perfectly functional; the only problem is that Helgen has not been destroyed; it's something that must be done so that the mod is complete.

:)

Note:

You'll find the definitive version of the script in the post below:

 

Edited by ladyonthemoon
0

Share this post


Link to post
Share on other sites

Helgen

Workflow:

1) A look in the CK:

Before taking care of Helgen, let's take a look at it from the top point of view:

Capture8.thumb.JPG.e0d1cddafe1a34c8ddc135130ef14d65.JPG

You'll need to enlarge the image to be able to see better.

As you can see, Helgen is a nightmare of triggers of all types (the coloured boxes) that overlap each other...

At the beginning of the game, the player arrives in the village from the East road down right, the keep being on the North. The yard where the player is created is on the South West. The dragon attack quest (MQDragonAttack) is started from MQ101, when the player gets off the cart; during the course of the attack, it's the player that makes the quest advance (and enable or disable the rubble and fires) by passing through the aforementioned triggers.

My plan is to create a new quest in which the dragon attack quest (MQ101DragonAttack) will advance and custom functions will:

  • move Ralof, Hadvar, Elenwell, Tullius, Uldric,
  • disable the unwanted npcs.

Since the player will not choose a side in the civil war right at the start of the game,  Hadvar will be moved near General Tullius in Solitude and Ralof near Ulfric in Windhelm. When the player chooses a side, Hadvar and Ralof will be participating to the war as they would if you had started the game in normal conditions.

Advancing the main quests and destroying Helgen

  1. create a new quest; make it "Start Game Enabled" and "Run Once",
  2. add two scripts to that quest: the Quest Form script and the Quest Script.

-----oOo----------oOo----------oOo-----

Examples of quest form script and quest script, in MQ101:

The "Quest Script" is named after the ID of the quest immediately followed by "QuestScript" or simply "Script". This is a script in which custom functions are defined and then called in the Quest Form script. For MQ101, it is MQ101QuestScript.

The Quest Form script is always named after the quest, immediately preceded by "QF_" and followed by the form ID number of the quest. For MQ101, it is "QF_MQ101_0003372B". It contains the stage fragments that advance the quest.

Capture9.thumb.JPG.3ddb160351e3b7afa7d38df1085558d1.JPG

We've already come across an example of how the "Quest Script" is used at the beginning of this tutorial, in MQ101, when spells are added to the player according to the race you chose.

The "add spells" function in the "Quest Script":

; add racial spells to player
function AddRaceSpells()
	; remove all racial spells first, just in case
	Actor player = Game.GetPlayer()
	RemoveRaceSpells(player)

	; add race spells
	Race playerRace = player.GetActorBase().GetRace()
	if playerRace == ArgonianRace

		elseif playerRace == BretonRace
			player.AddSpell(ConjureFamiliar)

		elseif playerRace == DarkElfRace  
			player.AddSpell(Sparks)

		elseif playerRace == HighElfRace  
			player.AddSpell(Fury)

		elseif playerRace == ImperialRace  

		elseif playerRace == KhajiitRace  

		elseif playerRace == NordRace  

		elseif playerRace == OrcRace  

		elseif playerRace == RedguardRace  

		elseif playerRace == WoodElfRace  

	endif

endFunction

and how it's called in the corresponding fragment in MQ101:

Capture10.JPG.6cead95495b8e1d3e9b8aa803f6c7768.JPG

-----oOo----------oOo----------oOo-----

This is how destroying Helgen will be handled.

  • add a "Quest Script" to the new quest and name it after your quest ID followed by QuestScript or at least Script. The quest I've created has "MOAS_InitQst" as ID; the name of the Quest Script will then be "MOAS_InitQstScript" (to avoid the redundancy between Qst and Quest),
  • generate the Quest Form Script. You do that by creating a stage, then adding an empty "log entry" and writing "; start mod" (or whatever you want) in the Papyrus fragment of this stage. Here is an image of the quest I created:

Capture11.thumb.JPG.767f0be606dfa7874667b32da4243b4d.JPG

Capture12.JPG.f5edc3a4222ae0035b542b9cbd0ea3e6.JPG

1) Advancing the dragon attack quest (MQ101DragonAttack), finishing the main quest (MQ101) and setting up MQ102:

  • in the Stage 0 Papyrus fragment of the quest, add the lines:
;advance and finish dragon attack quest
MQ101DragonAttack.SetStage(5)
MQ101DragonAttack.SetStage(10)
MQ101DragonAttack.SetStage(200)

;finish main quest
MQ101.SetStage (1000)

;start MQ102
MQ102.SetStage (5)
MQ102.SetStage (105)

SetStage (5)

2) Taking care of the unwanted npcs, useless stuff and moving the needed npcs to where they belong:

  • create the stage 5,
  • open the quest script you created and create the functions that will be called in stage 5:

- disabling stuff:

;stuff to be disabled properties
ObjectReference Property TEMPEndGate  Auto  
ObjectReference Property ChargenImodFXTrigger  Auto 


Function DisablingStuff ()
	TempEndGate.Disable()
	ChargenImodFXTrigger.Disable ()
EndFunction

- disabling npcs:

;actors to be disabled properties 
ReferenceAlias Property Justiciar01  Auto
ReferenceAlias Property Justiciar02  Auto
ReferenceAlias Property Priest  Auto
ReferenceAlias Property TortureRoomImperialSoldier1  Auto
ReferenceAlias Property TortureRoomStormcloak2  Auto
ReferenceAlias Property TortureRoomStormcloak3  Auto
ReferenceAlias Property Torturer  Auto
ReferenceAlias Property ImperialSoldier01  Auto  
ReferenceAlias Property ImperialSoldier02  Auto   
ReferenceAlias Property StormcloakPrisoner01  Auto 
ReferenceAlias Property StormcloakPrisoner02  Auto 
ReferenceAlias Property StormcloakPrisoner03  Auto 
ReferenceAlias Property StormcloakPrisoner04  Auto 
ReferenceAlias Property ImperialSoldierHelgen01  Auto 
ReferenceAlias Property ImperialSoldierFort01  Auto   
ReferenceAlias Property HelgenArcher01  Auto 
ReferenceAlias Property HelgenArcher02  Auto 
ReferenceAlias Property Prisoner01  Auto 
ReferenceAlias Property GunjarCorpse  Auto 


Function DisablingNPCs ()
	Justiciar01.GetActorRef().DisableNoWait()
	Justiciar02.GetActorRef().DisableNoWait()
	Priest.GetActorRef().DisableNoWait()
	TortureRoomImperialSoldier1.GetActorRef().DisableNoWait()
	TortureRoomStormcloak2.GetActorRef().DisableNoWait()
	TortureRoomStormcloak3.GetActorRef().DisableNoWait()
	Torturer.GetActorRef().DisableNoWait()
	ImperialSoldier01.GetActorRef().DisableNoWait()
	ImperialSoldier02.GetActorRef().DisableNoWait()
	StormcloakPrisoner01.GetActorRef().DisableNoWait()
	StormcloakPrisoner02.GetActorRef().DisableNoWait()
	StormcloakPrisoner03.GetActorRef().DisableNoWait()
	StormcloakPrisoner04.GetActorRef().DisableNoWait()
	ImperialSoldierHelgen01.GetActorRef().DisableNoWait()
	ImperialSoldierFort01.GetActorRef().DisableNoWait()
	HelgenArcher01.GetActorRef().DisableNoWait()
	HelgenArcher02.GetActorRef().DisableNoWait()
	Prisoner01.GetActorRef().DisableNoWait()
	GunjarCorpse.GetActorRef().DisableNoWait()
EndFunction

- moving and setting the npcs that must not be disabled:

;actors to be moved properties
ReferenceAlias Property Elenwen  Auto
ReferenceAlias Property Hadvar  Auto
ObjectReference Property MOAS_HadvarMarker  Auto 
ReferenceAlias Property Ralof  Auto
Outfit Property RalofOutfit Auto
ObjectReference Property MOAS_RalofMarker  Auto 


Function MovingNPCs ()
	Elenwen.GetActorRef().MoveToMyEditorLocation()
	Elenwen.GetActorRef().EnableNoWait()
	Hadvar.GetActorRef().MoveTo(MOAS_HadvarMarker)
	Hadvar.GetActorRef().EnableNoWait()
	Hadvar.GetActorRef().GetActorBase().SetEssential(false)
	Ralof.GetActorRef().MoveTo(MOAS_RalofMarker)
	Ralof.GetActorRef().EnableNoWait()
	Ralof.GetActorRef().SetOutfit(RalofOutfit)
	Ralof.GetActorRef().GetActorBase().SetEssential(false)
EndFunction
  • get back to the stage 5
  • in the "kmyQuest" drop down menu, add the quest script you created,
  • save the quest and open it again,
  • call the functions you just created:
kmyQuest.DisablingStuff ()
kmyQuest.DisablingNPCs ()
kmyQuest.MovingNPCs ()

- making the fact that the player has discovered and visited Helgen known. You'll need that in the civil war quest line.

  • in the cell "HelgenExterior02", create a "defaultSetStageTRIGPlayerOnly" trigger and set its properties as follows:

Capture17.thumb.JPG.279a89e9ef2467f8457a2f7154fbc9a2.JPG

In the quest you created, create the stage 15 and enter the following line in the Papyrus fragment (or nothing at all since it's just for memory):

;player has discovered Helgen

This is this stage done condition you'll have to use in the dialogue lines so that the player can start the main quest. See:

3) Specific things to be set inside the keep:

- the wall collapsing in the entrance: this effect is triggered by the player and is followed by the sound of the dragon roaring. If you choose to, you can disable that sound by setting its property in the trigger script to "none":

Capture15.thumb.JPG.da0cca5933d0dab65edf6b8018a607a7.JPG

- the bridge lever: it's set "Enable State to Opposite of Parent". The consequence is that it's disabled due to the fact that we advanced the quests earlier. Just untick "Set Enable State to Opposite of Parent" to make it come back.

Capture14.thumb.JPG.be895b95e1b4e35430507e99c5f072d4.JPG

- the drawbridge: this one is also triggered by the player but the current trigger will not work because of the absence of the "friend". You'll have to add a new trigger, a "defaultSetStageTRIGOnLeavePlayerOnly" trigger will do. Once you have created the trigger, set its properties as follows:

Capture13.thumb.JPG.9121428aaca4b1ecfa7bd35c652e3aeb.JPG

In the quest you created, create the stage 10 and enter the following code in the Papyrus fragment:

;trigger collapse
CollapsingBridgeAnim.enable()
game.ShakeCamera(CollapsingBridgeAnim,0.5,1.25)
game.ShakeController(0.5,0.35,1.0)
utility.wait(1.0)
If !CollapsingBridgeAnim.PlayAnimation("PlayAnim02")
;   debug.trace(self + "Collapse bridge animation fails to play")
EndIf
game.ShakeCamera(CollapsingBridgeAnim,1.0,2.0)
game.ShakeController(0.9,0.9,2)
utility.wait(0.5)
BridgeOriginal.disable()
utility.wait(1.0)
game.ShakeCamera(CollapsingBridgeAnim,0.6,2.0)
game.ShakeController(0.2,0.2,2.0)
BridgeDebris.enable()

You're done! Helgen is now as it looks like after you have escaped Helgen in the normal start.

:)

Edited by ladyonthemoon
0

Share this post


Link to post
Share on other sites

Posted (edited)

Final version of the script fragment added to MQ101, stage 0, quickstart 5:

;starting game
;moving the player to a dummy location
Actor PlayerRef = Alias_Player.GetActorRef()
PlayerRef.MoveTo(MOAS_DummyCellMarker)

;choosing where the player comes from
Int StartButton = MOAS_StartChoiceMessage.Show ()
If StartButton == 0
	PlayerRef.MoveTo(MOAS_CyrodiilGateMarker)
	ElseIf StartButton == 1
		PlayerRef.MoveTo(MOAS_HammerfellGateMarker)
	ElseIf StartButton == 2
		PlayerRef.MoveTo(MOAS_HighRockBorderMarker)
	ElseIf StartButton == 3
		PlayerRef.MoveTo(MOAS_MorrowindBorderNorthMarker)
	ElseIf StartButton == 4
		PlayerRef.MoveTo(MOAS_MorrowindSouthGateMarker)
EndIf

;fading the game out
Game.FadeOutGame(False, true, 1.0, 1.0)
Utility.Wait(0.5)

;emptying player's inventory
;adding new outfit and stuff to the player
PlayerRef.RemoveAllItems()
PlayerRef.SetOutfit(MOAS_PlayerOutfit)
PlayerRef.AddItem(MOAS_PlayerStartPackage, abSilent = true)
Utility.Wait(0.5)

;setting the time to 8 am
GameHour.SetValue(8)

;setting weather
SkyrimClear.ForceActive(true)
Utility.Wait(0.25)

;character creation
;popping up race menu
Game.ShowRaceMenu()

;adding spells based on race
kmyQuest.AddRaceSpells()
Utility.Wait(0.5)

;call offset stop on player
PlayerRef.PlayIdle(OffSetStop)
PlayerRef.AddItem(IronDagger, abSilent = 1)
PlayerRef.EquipItem(IronDagger, 0 ,1)

;overriding weather
Weather.ReleaseOverride()

;starting Helgen destroyed quest
MOAS_InitQst.SetStage (0)

;player has joined none of the available factions
kmyQuest.FactionPath = 0

;enabling save
Game.SetInChargen(false, false, false)
;saving game once the character has been created
Game.RequestSave()

 

Edited by ladyonthemoon
0

Share this post


Link to post
Share on other sites

What else need to be done?

  • There are lots of lines of dialogue that mention the player presence during the attack on Helgen. Use the View/Find Text feature to do that, then add conditions or modify them to your liking.

Capture16.thumb.JPG.d25eb6183caadf906f65ce0cd6f4d83d.JPG

  • If the player starts the civil war before discovering Helgen, they'll be stuck when they bring the message to Whiterun. Create a quest that will start at that moment, pointing the player at Helgen so that he discovers it.
  • As it is, the mod will not allow you to start the main quest; to do so, the player will have to discover Helgen first and then you'll have to go through the gate guard and Jarl Balgruuf lines of dialogues (in MQ102) and condition them so that they show up. So far, I've hold you hand, I'm now leaving this to you. I'm sure you'll understand fast what to do.

:)

Edited by ladyonthemoon
0

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now