[SKY] Teleporting Book script help

[Brecca]

Hey,
 
I'm currently trying to work on a script that when reading a book a message will pop up saying:
 
(1.Don't Read)   (2. Read).
 
Not reading the book will cancel the script while reading will teleport the player to a marker in a dungeon.  This is what I currently have:

 

 

Scriptname OghmaInfiniumScript extends ObjectReference

 

ObjectReference Property "location" auto

Message Property ChoiceMessage auto

 

Event OnRead(Actor akActor)

 

          if akActor == Game.GetPlayer()

 

                  int choice = ChoiceMessage.Show()

                  if     (choice == 0)

                           ; do nothing

                  elseif (choice == 1)

                              Game.GetPlayer().moveto("location")

                  endif

           endIf

EndEvent

 

*This originally was the Ogh.Inf. script*

 

Currently this isn't compiling though, so I'm checking to see if I had done anything wrong.  Also note that my experience with scripting goes back to Monday

 

Besides that I'm also wanting to add a Return function to the script so that when the book is read again it sends the player back to the original location.  I am not so sure on where to start.

[DsoS]

Scriptname CHANGEYOURSCRIPTNAME!!!!! extends ObjectReference
 
ObjectReference Property TeleportLocation auto
Message Property ChoiceMessage auto
 
Event OnRead()
 
          if Game.GetPlayer() == True
 
                  int choice = ChoiceMessage.Show()
                  if     (choice == 0)
                           ; do nothing
                  elseif (choice == 1)
                              Game.GetPlayer().moveto(TeleportLocation)
                  endif
           endIf
EndEvent

 

First, make sure you change the Script name, or you will overwrite the oghma book script... very bad for your mod and anyone who plays it.

 

You don't need the quote marks on the "location" of the property or in the script.

 

OnRead() does not require the (Actor AkActor) stuff. I removed that and changed the script to make sure the player can activate it.

 

We will tackle one thing at a time.

 

See if you can compile this without any issues. If the compiler gives an error, copy that complete error and post it here, please.

Edited July 6, 2013 by DsoS

[Ghaunadaur]

DsoS is right, just a small addition. You can't name a property 'Location', because that's a property type. Name it 'TeleportLocation' or something like that.

[DsoS]

LOL that is correct, why didn't I see that? I'll fix it in my script above so they can copy and paste.

 

Okay, its changed.

 

Great eye Ghaunadaur!

Edited July 6, 2013 by DsoS

[Brecca]

Great news!

 

It compiled successfully and worked on the first try in game.  

 

So, for the Return function, apparently I would need to make a script that drops a marker in my place before teleport then reference back to it when the book is read again? So would I need to use a true/false set up?

 

Also, is there a way I can delay the script to wait for the book to open before the choice?  Right now the choices pop up before the book opens.  Really a nitpick, if its too much work I won't bother.

[DsoS]

The return function, I'm not sure about. I have not tried anything like that. Maybe Ghaunadaur or WillieSea can chime in on that.

 

For a wait time, place the line below the "if Game.GetPlayer() == True" line and above the "int choice .... " line

Utility.Wait(MyWaitTime)

 

Below the Message Property:

 

Int Property MyWaitTime Auto

[Ghaunadaur]

There are probably several ways to do this. I would make two states in the script, the first state to teleport to the 'TeleportLocation', the second to return to the original location. For the delay, WaitMenuMode would be better in this case I believe, because the game is in menu mode while a book is opened. You could try with this script:

 

ScriptName YourScriptName extends ObjectReference

ObjectReference Property TeleportLocation auto
Message Property ChoiceMessage auto
Static Property XMarkerHeading auto
ObjectReference ReturnMarker
Actor Property PlayerRef auto

auto State TeleportState
Event OnRead()
		Utility.WaitMenuMode(1.0)		
		int choice = ChoiceMessage.Show()
        if (choice == 0)
			; do nothing
        elseif (choice == 1)
			ReturnMarker = PlayerRef.PlaceAtMe(XMarkerHeading, 1)
			PlayerRef.MoveTo(TeleportLocation)
			GotoState("ReturnState")
        endif    
EndEvent
EndState

State ReturnState
Event OnRead()
		Utility.WaitMenuMode(1.0)
		int choice = ChoiceMessage.Show()
        if (choice == 0)
			; do nothing
        elseif (choice == 1)
			PlayerRef.MoveTo(ReturnMarker)
			ReturnMarker.Delete()
			GotoState("TelePortState")
		endif
EndEvent
EndState

 

[WillieSea]

When you teleport 'to' your location, you first drop an XmarkerHeading that you placed in the world, with a reference name and an ObjectReference in the script pointing to it.

 

When you decide to teleport 'back' from whence they came, you move to the marker.

 

You only move your 'marker' when you go 'home'.

[Brecca]

What do I need to set up for the properties? Or do I leave them be?

[WillieSea]

What do you mean?

 

You link the property of the xMarkerHeading in your script to the xMarkerHeading you placed in the world.

[Ghaunadaur]

For the properties 'PlayerRef' and 'XMarkerHeading' just hit the auto-fill button.

[Brecca]

Whelp, that did it

 

Really appreciate the help, I am very excited, Thank you!

[DsoS]

Glad to hear and glad to help (all of us)

 

Could you post your script, please? This way if someone is looking for something similar or the same, they can use this script as a base.

[Brecca]

ScriptName aaBookTeleportScript extends ObjectReference

ObjectReference Property TeleportLocation auto
Message Property ChoiceMessage auto
Static Property XMarkerHeading auto
ObjectReference ReturnMarker
Actor Property PlayerRef auto

auto State TeleportState
Event OnRead()
		Utility.WaitMenuMode(1.0)		
		int choice = ChoiceMessage.Show()
        if (choice == 0)
			; do nothing
        elseif (choice == 1)
			ReturnMarker = PlayerRef.PlaceAtMe(XMarkerHeading, 1)
			PlayerRef.MoveTo(TeleportLocation)
			GotoState("ReturnState")
        endif    
EndEvent
EndState

State ReturnState
Event OnRead()
		Utility.WaitMenuMode(1.0)
		int choice = ChoiceMessage.Show()
        if (choice == 0)
			; do nothing
        elseif (choice == 1)
			PlayerRef.MoveTo(ReturnMarker)
			ReturnMarker.Delete()
			GotoState("TelePortState")
		endif
EndEvent
EndState

Here we are, one teleporting book script

[WillieSea]

The 'auto fill' button only works if you put a unique name on the world objects reference name. And you used that reference name in your script for the name of the property.

Just saying...

[DsoS]

Thank You